本日は昨日に引き続きMRTKStandardShaderの調査枠です。
昨日はTriplanarMappingに関してどのようなものか？ どのようなことができるかを見ていきました。
本日はShaderコードを見ていきます。
〇Properiesブロック
ProperiesブロックではTriplanarMappingを使用するために次の分を追加しています。
Properties
{
// Main maps.
_Color("Color", Color) = (1.0, 1.0, 1.0, 1.0)
_MainTex("Albedo", 2D) = "white" {}
...
[Toggle(_TRIPLANAR_MAPPING)] _EnableTriplanarMapping("Triplanar Mapping", Float) = 0.0
[Toggle(_LOCAL_SPACE_TRIPLANAR_MAPPING)] _EnableLocalSpaceTriplanarMapping("Local Space", Float) = 0.0
_TriplanarMappingBlendSharpness("Blend Sharpness", Range(1.0, 16.0)) = 4.0
}
[Toggle()]のアトリビュートはUnityC#でいうbool型同様のチェックボックスを表示させます。
EnableTriplanarMapping, EnableLocalSpaceTriplanarMappingはどちらも右辺が０なので初期状態ではチェックが入っておらず無効の状態になっています。
〇v2f構造体
v2f構造体では頂点シェーダーで処理した情報をどのように使用するかを記述します。
TriplanarMappingに関する記述は次になります。
#if defined(_TRIPLANAR_MAPPING)
fixed3 worldNormal : COLOR3;
fixed3 triplanarNormal : COLOR4;
float3 triplanarPosition : TEXCOORD6;
#elif defined(_NORMAL_MAP)//TriplanarMappingを使用しない場合でNormalMapを使用する場合
fixed3 tangentX : COLOR3;
fixed3 tangentY : COLOR4;
fixed3 tangentZ : COLOR5;
#else
fixed3 worldNormal : COLOR3;//TriplanaMappingを使用しない場合
#endif
worldNormal、triplanarNormalはそれぞれCOLOR3、COLOR4の頂点の色として扱われます。
triplanarPositionはTEXCOORD6のUV座標として扱われます。
〇頂点シェーダー
PropertiesでTriplanaerMappingが有効化されている場合頂点シェーダーで次の処理が行われます。
#if defined(_TRIPLANAR_MAPPING)
o.worldNormal = worldNormal;
#if defined(_LOCAL_SPACE_TRIPLANAR_MAPPING)
o.triplanarNormal = localNormal;
o.triplanarPosition = vertexPosition;
#else
o.triplanarNormal = worldNormal;
o.triplanarPosition = o.worldPosition;
#endif
#else
o.worldNormal = worldNormal;
#endif
ここで[LocalSpace]が使用されていない場合は次のようになります。
#if defined(_TRIPLANAR_MAPPING)
o.worldNormal = worldNormal;
o.triplanarNormal = worldNormal;
o.triplanarPosition = o.worldPosition;
#else
o.worldNormal = worldNormal;
#endif
v2f構造体のworldNormalは頂点シェーダーのworldNormal
fixed3 localNormal = v.normal; fixed3 worldNormal = UnityObjectToWorldNormal(localNormal);
つまり頂点の法線をUnity座標に変換したものが代入されます。
o.triplanarNormal = worldNormal; o.triplanarPosition = o.worldPosition;
同じくv2fのtriplanarNormalにも頂点の法線が代入されv2fのtriplanarPositionはv2fのworldPositionと同じとされます。
逆にTriplanarMappingの[LocalSpace]が有効化されている場合は次のようになります。
#if defined(_TRIPLANAR_MAPPING)
o.worldNormal = worldNormal;
#if defined(_LOCAL_SPACE_TRIPLANAR_MAPPING)
o.triplanarNormal = localNormal;
o.triplanarPosition = vertexPosition;
#else
...
v2fのtriplanarNormalはlocalNormalで頂点の持つ法線情報そのものが入ります。
triplanarPositionも
float4 vertexPosition = v.vertex;
頂点自身の持つ位置が使用されます。
つまりLocalSpaceを有効化するとUnityでの座標系に依存しないようになります。
頂点シェーダーまではTriplanarMappingを使用する際の頂点の準備のような処理が行われました。
ここまでで特別な処理は行われていません。
TriplanarMappingの処理はフラグメントシェーダーで行われています。
〇フラグメントシェーダー
fixed4 frag(v2f i, fixed facing : VFACE) : SV_Target
{
#if defined(_TRIPLANAR_MAPPING)
// Calculate triplanar uvs and apply texture scale and offset values like TRANSFORM_TEX.
fixed3 triplanarBlend = pow(abs(i.triplanarNormal), _TriplanarMappingBlendSharpness);
triplanarBlend /= dot(triplanarBlend, fixed3(1.0, 1.0, 1.0));
float2 uvX = i.triplanarPosition.zy * _MainTex_ST.xy + _MainTex_ST.zw;
float2 uvY = i.triplanarPosition.xz * _MainTex_ST.xy + _MainTex_ST.zw;
float2 uvZ = i.triplanarPosition.xy * _MainTex_ST.xy + _MainTex_ST.zw;
// Ternary operator is 2 instructions faster than sign() when we don't care about zero returning a zero sign.
float3 axisSign = i.triplanarNormal < 0 ? -1 : 1;
uvX.x *= axisSign.x;
uvY.x *= axisSign.y;
uvZ.x *= -axisSign.z;
#endif
// Texturing.
#if defined(_TRIPLANAR_MAPPING)
fixed4 albedo = tex2D(_MainTex, uvX) * triplanarBlend.x +
tex2D(_MainTex, uvY) * triplanarBlend.y +
tex2D(_MainTex, uvZ) * triplanarBlend.z;
#else
fixed4 albedo = tex2D(_MainTex, i.uv);
#endif
...
#if defined(_NORMAL_MAP)
#if defined(_TRIPLANAR_MAPPING)
fixed3 tangentNormalX = UnpackScaleNormal(tex2D(_NormalMap, uvX), _NormalMapScale);
fixed3 tangentNormalY = UnpackScaleNormal(tex2D(_NormalMap, uvY), _NormalMapScale);
fixed3 tangentNormalZ = UnpackScaleNormal(tex2D(_NormalMap, uvZ), _NormalMapScale);
tangentNormalX.x *= axisSign.x;
tangentNormalY.x *= axisSign.y;
tangentNormalZ.x *= -axisSign.z;
// Swizzle world normals to match tangent space and apply Whiteout normal blend.
tangentNormalX = fixed3(tangentNormalX.xy + i.worldNormal.zy, tangentNormalX.z * i.worldNormal.x);
tangentNormalY = fixed3(tangentNormalY.xy + i.worldNormal.xz, tangentNormalY.z * i.worldNormal.y);
tangentNormalZ = fixed3(tangentNormalZ.xy + i.worldNormal.xy, tangentNormalZ.z * i.worldNormal.z);
// Swizzle tangent normals to match world normal and blend together.
worldNormal = normalize(tangentNormalX.zyx * triplanarBlend.x +
tangentNormalY.xzy * triplanarBlend.y +
tangentNormalZ.xyz * triplanarBlend.z);
#else
fixed3 tangentNormal = UnpackScaleNormal(tex2D(_NormalMap, i.uv), _NormalMapScale);
worldNormal.x = dot(i.tangentX, tangentNormal);
worldNormal.y = dot(i.tangentY, tangentNormal);
worldNormal.z = dot(i.tangentZ, tangentNormal);
worldNormal = normalize(worldNormal) * facing;
#endif
#else
worldNormal = normalize(i.worldNormal) * facing;
#endif
#endif
...
return output;
}
ここがコアとなる部分のようです。
今回も長くなってしまったので理解を深めるために次回フラグメントシェーダーを見ていきます。
〇今回作成したShader
// Copyright (c) Microsoft Corporation. All rights reserved.
// Licensed under the MIT License.
Shader "Custom/MRTKStandardTriplanarMapping"
{
Properties
{
// Main maps.
_Color("Color", Color) = (1.0, 1.0, 1.0, 1.0)
_MainTex("Albedo", 2D) = "white" {}
[Enum(AlbedoAlphaMode)] _AlbedoAlphaMode("Albedo Alpha Mode", Float) = 0 // "Transparency"
[Toggle] _AlbedoAssignedAtRuntime("Albedo Assigned at Runtime", Float) = 0.0
_Cutoff("Alpha Cutoff", Range(0.0, 1.0)) = 0.5
_Metallic("Metallic", Range(0.0, 1.0)) = 0.0
_Smoothness("Smoothness", Range(0.0, 1.0)) = 0.5
[Toggle(_NORMAL_MAP)] _EnableNormalMap("Enable Normal Map", Float) = 0.0
[NoScaleOffset] _NormalMap("Normal Map", 2D) = "bump" {}
_NormalMapScale("Scale", Float) = 1.0
[Toggle(_TRIPLANAR_MAPPING)] _EnableTriplanarMapping("Triplanar Mapping", Float) = 0.0
[Toggle(_LOCAL_SPACE_TRIPLANAR_MAPPING)] _EnableLocalSpaceTriplanarMapping("Local Space", Float) = 0.0
_TriplanarMappingBlendSharpness("Blend Sharpness", Range(1.0, 16.0)) = 4.0
}
SubShader
{
Pass
{
Name "Main"
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma shader_feature _ _ALPHATEST_ON _ALPHABLEND_ON
#pragma shader_feature _DISABLE_ALBEDO_MAP
#pragma shader_feature _ _METALLIC_TEXTURE_ALBEDO_CHANNEL_A _SMOOTHNESS_TEXTURE_ALBEDO_CHANNEL_A
#pragma shader_feature _NORMAL_MAP
#pragma shader_feature _TRIPLANAR_MAPPING
#pragma shader_feature _LOCAL_SPACE_TRIPLANAR_MAPPING
#pragma shader_feature _DIRECTIONAL_LIGHT
#include "UnityCG.cginc"
#include "UnityStandardConfig.cginc"
#include "UnityStandardUtils.cginc"
#include "MixedRealityShaderUtils.cginc"
// This define will get commented in by the UpgradeShaderForLightweightRenderPipeline method.
//#define _LIGHTWEIGHT_RENDER_PIPELINE
#if defined(_TRIPLANAR_MAPPING) || defined(_DIRECTIONAL_LIGHT)
#define _NORMAL
#else
#undef _NORMAL
#endif
#if defined(_NORMAL)
#define _WORLD_POSITION
#else
#undef _WORLD_POSITION
#endif
#if defined(_DIRECTIONAL_LIGHT)
#define _FRESNEL
#else
#undef _FRESNEL
#endif
#if defined(_TRIPLANAR_MAPPING) || defined(_NORMAL_MAP)
#define _UV
#else
#undef _UV
#endif
struct appdata_t
{
float4 vertex : POSITION;
// The default UV channel used for texturing.
float2 uv : TEXCOORD0;
// Used for smooth normal data (or UGUI scaling data).
float4 uv2 : TEXCOORD2;
// Used for UGUI scaling data.
float2 uv3 : TEXCOORD3;
fixed3 normal : NORMAL;
#if defined(_NORMAL_MAP)
fixed4 tangent : TANGENT;
#endif
UNITY_VERTEX_INPUT_INSTANCE_ID
};
struct v2f
{
float4 position : SV_POSITION;
#if defined(_UV)
float2 uv : TEXCOORD0;
#endif
#if defined(_WORLD_POSITION)
float3 worldPosition : TEXCOORD2;
#endif
#if defined(_SCALE)
float3 scale : TEXCOORD3;
#endif
#if defined(_NORMAL)
#if defined(_TRIPLANAR_MAPPING)
fixed3 worldNormal : COLOR3;
fixed3 triplanarNormal : COLOR4;
float3 triplanarPosition : TEXCOORD6;
#elif defined(_NORMAL_MAP)
fixed3 tangentX : COLOR3;
fixed3 tangentY : COLOR4;
fixed3 tangentZ : COLOR5;
#else
fixed3 worldNormal : COLOR3;
#endif
#endif
UNITY_VERTEX_OUTPUT_STEREO
};
fixed4 _Color;
sampler2D _MainTex;
fixed4 _MainTex_ST;
fixed _Metallic;
fixed _Smoothness;
#if defined(_NORMAL_MAP)
sampler2D _NormalMap;
float _NormalMapScale;
#endif
#if defined(_TRIPLANAR_MAPPING)
float _TriplanarMappingBlendSharpness;
#endif
#if defined(_DIRECTIONAL_LIGHT)
fixed4 _LightColor0;
#endif
#if defined(_DIRECTIONAL_LIGHT)
static const fixed _MinMetallicLightContribution = 0.7;
static const fixed _IblContribution = 0.1;
#endif
#if defined(_FRESNEL)
static const float _FresnelPower = 8.0;
#endif
v2f vert(appdata_t v)
{
v2f o;
UNITY_SETUP_INSTANCE_ID(v);
UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);
float4 vertexPosition = v.vertex;
#if defined(_WORLD_POSITION)
float3 worldVertexPosition = mul(unity_ObjectToWorld, vertexPosition).xyz;
#endif
#if defined(_SCALE)
o.scale.x = length(mul(unity_ObjectToWorld, float4(1.0, 0.0, 0.0, 0.0)));
o.scale.y = length(mul(unity_ObjectToWorld, float4(0.0, 1.0, 0.0, 0.0)));
o.scale.z = length(mul(unity_ObjectToWorld, float4(0.0, 0.0, 1.0, 0.0)));
#endif
fixed3 localNormal = v.normal;
#if defined(_NORMAL)
fixed3 worldNormal = UnityObjectToWorldNormal(localNormal);
#endif
o.position = UnityObjectToClipPos(vertexPosition);
#if defined(_WORLD_POSITION)
o.worldPosition.xyz = worldVertexPosition;
#endif
#if defined(_UV)
o.uv = TRANSFORM_TEX(v.uv, _MainTex);
#endif
#if defined(_NORMAL)
#if defined(_TRIPLANAR_MAPPING)
o.worldNormal = worldNormal;
#if defined(_LOCAL_SPACE_TRIPLANAR_MAPPING)
o.triplanarNormal = localNormal;
o.triplanarPosition = vertexPosition;
#else
o.triplanarNormal = worldNormal;
o.triplanarPosition = o.worldPosition;
#endif
#elif defined(_NORMAL_MAP)
fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed tangentSign = v.tangent.w * unity_WorldTransformParams.w;
fixed3 worldBitangent = cross(worldNormal, worldTangent) * tangentSign;
o.tangentX = fixed3(worldTangent.x, worldBitangent.x, worldNormal.x);
o.tangentY = fixed3(worldTangent.y, worldBitangent.y, worldNormal.y);
o.tangentZ = fixed3(worldTangent.z, worldBitangent.z, worldNormal.z);
#else
o.worldNormal = worldNormal;
#endif
#endif
return o;
}
fixed4 frag(v2f i, fixed facing : VFACE) : SV_Target
{
#if defined(_TRIPLANAR_MAPPING)
// Calculate triplanar uvs and apply texture scale and offset values like TRANSFORM_TEX.
fixed3 triplanarBlend = pow(abs(i.triplanarNormal), _TriplanarMappingBlendSharpness);
triplanarBlend /= dot(triplanarBlend, fixed3(1.0, 1.0, 1.0));
float2 uvX = i.triplanarPosition.zy * _MainTex_ST.xy + _MainTex_ST.zw;
float2 uvY = i.triplanarPosition.xz * _MainTex_ST.xy + _MainTex_ST.zw;
float2 uvZ = i.triplanarPosition.xy * _MainTex_ST.xy + _MainTex_ST.zw;
// Ternary operator is 2 instructions faster than sign() when we don't care about zero returning a zero sign.
float3 axisSign = i.triplanarNormal < 0 ? -1 : 1;
uvX.x *= axisSign.x;
uvY.x *= axisSign.y;
uvZ.x *= -axisSign.z;
#endif
// Texturing.
#if defined(_TRIPLANAR_MAPPING)
fixed4 albedo = tex2D(_MainTex, uvX) * triplanarBlend.x +
tex2D(_MainTex, uvY) * triplanarBlend.y +
tex2D(_MainTex, uvZ) * triplanarBlend.z;
#else
fixed4 albedo = tex2D(_MainTex, i.uv);
#endif
albedo *= _Color;
// Normal calculation.
#if defined(_NORMAL)
fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPosition.xyz));
fixed3 worldNormal;
#if defined(_NORMAL_MAP)
#if defined(_TRIPLANAR_MAPPING)
fixed3 tangentNormalX = UnpackScaleNormal(tex2D(_NormalMap, uvX), _NormalMapScale);
fixed3 tangentNormalY = UnpackScaleNormal(tex2D(_NormalMap, uvY), _NormalMapScale);
fixed3 tangentNormalZ = UnpackScaleNormal(tex2D(_NormalMap, uvZ), _NormalMapScale);
tangentNormalX.x *= axisSign.x;
tangentNormalY.x *= axisSign.y;
tangentNormalZ.x *= -axisSign.z;
// Swizzle world normals to match tangent space and apply Whiteout normal blend.
tangentNormalX = fixed3(tangentNormalX.xy + i.worldNormal.zy, tangentNormalX.z * i.worldNormal.x);
tangentNormalY = fixed3(tangentNormalY.xy + i.worldNormal.xz, tangentNormalY.z * i.worldNormal.y);
tangentNormalZ = fixed3(tangentNormalZ.xy + i.worldNormal.xy, tangentNormalZ.z * i.worldNormal.z);
// Swizzle tangent normals to match world normal and blend together.
worldNormal = normalize(tangentNormalX.zyx * triplanarBlend.x +
tangentNormalY.xzy * triplanarBlend.y +
tangentNormalZ.xyz * triplanarBlend.z);
#else
fixed3 tangentNormal = UnpackScaleNormal(tex2D(_NormalMap, i.uv), _NormalMapScale);
worldNormal.x = dot(i.tangentX, tangentNormal);
worldNormal.y = dot(i.tangentY, tangentNormal);
worldNormal.z = dot(i.tangentZ, tangentNormal);
worldNormal = normalize(worldNormal) * facing;
#endif
#else
worldNormal = normalize(i.worldNormal) * facing;
#endif
#endif
fixed pointToLight = 1.0;
fixed3 fluentLightColor = fixed3(0.0, 0.0, 0.0);
// Blinn phong lighting.
#if defined(_DIRECTIONAL_LIGHT)
#if defined(_LIGHTWEIGHT_RENDER_PIPELINE)
float4 directionalLightDirection = _MainLightPosition;
#else
float4 directionalLightDirection = _WorldSpaceLightPos0;
#endif
fixed diffuse = max(0.0, dot(worldNormal, directionalLightDirection));
fixed specular = 0.0;
#endif
fixed3 ibl = unity_IndirectSpecColor.rgb;
// Fresnel lighting.
#if defined(_FRESNEL)
fixed fresnel = 1.0 - saturate(abs(dot(worldViewDir, worldNormal)));
fixed3 fresnelColor = unity_IndirectSpecColor.rgb * (pow(fresnel, _FresnelPower) * max(_Smoothness, 0.5));
#endif
// Final lighting mix.
fixed4 output = albedo;
fixed3 ambient = glstate_lightmodel_ambient + fixed3(0.25, 0.25, 0.25);
fixed minProperty = min(_Smoothness, _Metallic);
#if defined(_DIRECTIONAL_LIGHT)
fixed oneMinusMetallic = (1.0 - _Metallic);
output.rgb = lerp(output.rgb, ibl, minProperty);
fixed3 directionalLightColor = _LightColor0.rgb;
output.rgb *= lerp((ambient + directionalLightColor * diffuse + directionalLightColor * specular) * max(oneMinusMetallic, _MinMetallicLightContribution), albedo, minProperty);
output.rgb += (directionalLightColor * albedo * specular) + (directionalLightColor * specular * _Smoothness);
output.rgb += ibl * oneMinusMetallic * _IblContribution;
#endif
#if defined(_FRESNEL)
output.rgb += fresnelColor * (1.0 - minProperty);
#endif
return output;
}
ENDCG
}
}
Fallback "Hidden/InternalErrorShader"
}
