夜風のMixedReality

xRと出会って変わった人生と出会った技術を書き残すためのGeekなHoloRangerの居場所

MRTKのWireFrameShaderを覗いてみる。 SubShaderブロック

本日は昨日に引き続きMRTKのShader学習枠です。

昨日はMRTKで提供されているWireFrameShaderのSubShaderブロックを見ていきました。

本日はSubShaderをざっくり見ていきます。

SubShaderとは、ShaderLabがメッシュを描画するとき、使用するシェーダーを見つけ、グラフィックスカードで実行するブロックになります。

 SubShader
    {
        Tags { "RenderType" = "Opaque" }
        Blend[_SrcBlend][_DstBlend]
        BlendOp[_BlendOp]
        ZTest[_ZTest]
        ZWrite[_ZWrite]
        Cull[_CullMode]
        Offset[_ZOffsetFactor],[_ZOffsetUnits]
        ColorMask[_ColorWriteMask]

        Pass
        {
            Offset 50, 100

            CGPROGRAM
   ...
            ENDCG
        }
    }

〇Tagブロック

''' Tags { "RenderType" = "Opaque" } '''

TagブロックはShaderの処理をどのようにレンダリングエンジンで描画するかを設定する項目です。

WireframeShaderの場合初期値として "RenderType" = "Opaqueで不透明のShaderとして描画されます。

〇Blend

Shaderのブレンドは透明度をもつShaderのα値の合成に使用されるものです。

  Blend[_SrcBlend][_DstBlend]

_SrcBlendはプロパティで初期値が Oneに指定されておりこれはShaderで処理されたそのままの色を意味します。

_DstBlendはプロパティで初期値が Zero に指定されており、これはすでに描画されている色×0=黒を意味します。

よって初期値の場合Blendは

Blend One Zero

となります。

これはShaderで処理されたそのままの色を使用することを意味します。

〇BlendOp

BlendOp[_BlendOp]

BlendOpはBlendの操作のオプションでただ合成する代わりに指定した操作を行います。

初期値でAddが指定されており これは同時にソースとディストネーションを追加します。しかし初期値の場合は透明度を無視した処理のようなのでたいして意味はないようです。

〇Ztest

ZTest[_ZTest]

ZTestとは深度(距離)が異なる二つのピクセルが重なっている場合どちらを出力するかの設定になります。

初期値ではLessEqualが指定されておりこれは遠くにある順番に描画されます。

〇ZWrite

ZWriteは深度情報を書き込むかという設定です。 こちらも透明度を持つオブジェクトで使用されるものです。 初期値でOnが設定されており深度情報を使用する設定になっているようです。

〇Cull

 Cull[_CullMode]

Cullはカリングを指し、メッシュの面のどちら側を描画するかを指定します。(正確にはどちらを描画せずカリングするかを指定します。)

初期値はBackが指定されているため表面が描画され裏面がカリングされます。

〇Offset

Offset[_ZOffsetFactor],[_ZOffsetUnits]

デプスのオフセットになります。 初期値ではどちらもゼロが指定されるため深度情報のずれはありません。

〇ColorMask

ColorMask[_ColorWriteMask]

マスクするカラーチャンネルを指定します。

すべてのチャンネルをマスクし何も描画しないのがColorMask0すべてを描画する設定がColorMask15となります。 今回は15が初期値であり、すべて描画する設定になっています。

WireframeShaderは初期値でα値を使用しない不透明Shaderですが、透明のShaderとしても使用できるようにMixedRealityShaderの定型に習い作成されているようです。

〇Shader全文

// Copyright (c) Microsoft Corporation.
// Licensed under the MIT License.

///
/// Basic wireframe shader that can be used for rendering spatial mapping meshes.
///
Shader "Mixed Reality Toolkit/Wireframe"
{
    Properties
    {
        // Advanced options.
        [Enum(RenderingMode)] _Mode("Rendering Mode", Float) = 0                                     // "Opaque"
        [Enum(CustomRenderingMode)] _CustomMode("Mode", Float) = 0                                   // "Opaque"
        [Enum(UnityEngine.Rendering.BlendMode)] _SrcBlend("Source Blend", Float) = 1                 // "One"
        [Enum(UnityEngine.Rendering.BlendMode)] _DstBlend("Destination Blend", Float) = 0            // "Zero"
        [Enum(UnityEngine.Rendering.BlendOp)] _BlendOp("Blend Operation", Float) = 0                 // "Add"
        [Enum(UnityEngine.Rendering.CompareFunction)] _ZTest("Depth Test", Float) = 4                // "LessEqual"
        [Enum(DepthWrite)] _ZWrite("Depth Write", Float) = 1                                         // "On"
        _ZOffsetFactor("Depth Offset Factor", Float) = 0                                             // "Zero"
        _ZOffsetUnits("Depth Offset Units", Float) = 0                                               // "Zero"
        [Enum(UnityEngine.Rendering.ColorWriteMask)] _ColorWriteMask("Color Write Mask", Float) = 15 // "All"
        [Enum(UnityEngine.Rendering.CullMode)] _CullMode("Cull Mode", Float) = 2                     // "Back"
        _RenderQueueOverride("Render Queue Override", Range(-1.0, 5000)) = -1

        _BaseColor("Base color", Color) = (0.0, 0.0, 0.0, 1.0)
        _WireColor("Wire color", Color) = (1.0, 1.0, 1.0, 1.0)
        _WireThickness("Wire thickness", Range(0, 800)) = 100
    }
    SubShader
    {
        Tags { "RenderType" = "Opaque" }
        Blend[_SrcBlend][_DstBlend]
        BlendOp[_BlendOp]
        ZTest[_ZTest]
        ZWrite[_ZWrite]
        Cull[_CullMode]
        Offset[_ZOffsetFactor],[_ZOffsetUnits]
        ColorMask[_ColorWriteMask]

        Pass
        {
            Offset 50, 100

            CGPROGRAM
            #pragma vertex vert
            #pragma geometry geom
            #pragma fragment frag

            #if defined(SHADER_API_D3D11)
            #pragma target 5.0
            #endif

            #include "UnityCG.cginc"

            float4 _BaseColor;
            float4 _WireColor;
            float _WireThickness;

            // Based on approach described in Shader-Based Wireframe Drawing (2008)
            // http://orbit.dtu.dk/en/publications/id(13e2122d-bec7-48de-beca-03ce6ea1c3f1).html

            struct v2g
            {
                float4 viewPos : SV_POSITION;
                UNITY_VERTEX_OUTPUT_STEREO
            };

            v2g vert(appdata_base v)
            {
                UNITY_SETUP_INSTANCE_ID(v);
                v2g o;
                o.viewPos = UnityObjectToClipPos(v.vertex);
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);
                return o;
            }

            // inverseW is to counteract the effect of perspective-correct interpolation so that the lines
            // look the same thickness regardless of their depth in the scene.
            struct g2f
            {
                float4 viewPos : SV_POSITION;
                float inverseW : TEXCOORD0;
                float3 dist : TEXCOORD1;
                UNITY_VERTEX_OUTPUT_STEREO
            };

            [maxvertexcount(3)]
            void geom(triangle v2g i[3], inout TriangleStream<g2f> triStream)
            {
                // Calculate the vectors that define the triangle from the input points.
                float2 point0 = i[0].viewPos.xy / i[0].viewPos.w;
                float2 point1 = i[1].viewPos.xy / i[1].viewPos.w;
                float2 point2 = i[2].viewPos.xy / i[2].viewPos.w;

                // Calculate the area of the triangle.
                float2 vector0 = point2 - point1;
                float2 vector1 = point2 - point0;
                float2 vector2 = point1 - point0;
                float area = abs(vector1.x * vector2.y - vector1.y * vector2.x);

                float3 distScale[3];
                distScale[0] = float3(area / length(vector0), 0, 0);
                distScale[1] = float3(0, area / length(vector1), 0);
                distScale[2] = float3(0, 0, area / length(vector2));

                float wireScale = 800 - _WireThickness;

                // Output each original vertex with its distance to the opposing line defined
                // by the other two vertices.
                g2f o;
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(o);

                [unroll]
                for (uint idx = 0; idx < 3; ++idx)
                {
                   o.viewPos = i[idx].viewPos;
                   o.inverseW = 1.0 / o.viewPos.w;
                   o.dist = distScale[idx] * o.viewPos.w * wireScale;
                   UNITY_TRANSFER_VERTEX_OUTPUT_STEREO(i[idx], o);
                   triStream.Append(o);
                }
            }

            float4 frag(g2f i) : COLOR
            {
                // Calculate  minimum distance to one of the triangle lines, making sure to correct
                // for perspective-correct interpolation.
                float dist = min(i.dist[0], min(i.dist[1], i.dist[2])) * i.inverseW;

                // Make the intensity of the line very bright along the triangle edges but fall-off very
                // quickly.
                float I = exp2(-2 * dist * dist);

                return I * _WireColor + (1 - I) * _BaseColor;
            }
            ENDCG
        }
    }

    FallBack "Mixed Reality Toolkit/Standard"
    CustomEditor "Microsoft.MixedReality.Toolkit.Editor.MixedRealityWireframeShaderGUI"
}