ゼロから始めるUnityShader開発 第六章 モザイクシェーダー

本日はShader学習枠です。また2022年最後の記事になります。本年は毎日ブログを更新できました。23年も毎日更新はもちろんのことですが、質もよくしていきたいと思います。

〇モザイクシェーダー

今回は画像をmosaicで表示する表現を紹介します。

①新規のUnlitShaderを作成します。

デフォルトでは画像を張り付けることができます。

今回はこのシェーダーを改造して貼り付ける画像をモザイクにします。

②ShaderのHlsl文内に次の関数を記述します。

            void Posterize_float2(float2 In, float2 Steps, out float2 Out)
            {
                Out = floor(In / (1 / Steps)) * (1 / Steps);
            }

これはPosterizeというUnityのShaderGraphで実装されているノードの処理になります。

docs.unity3d.com

Posterizeは第一引数Inで与えた値をStepsで指定した任意の数で分割したものをOutで出力するという処理です。

　具体的にはfloor(x)はhlslで定義されている組み込み関数で、xの小数部を切り取った整数を返します。

　例えば次のようになります。

 floor(1.2121) → 1
 floor(0.12)　→ 0
floor(3.14)→3

learn.microsoft.com

Posterize_float2関数のInにUVを与えることでUVの値を段階的に区切ることができます。

　テクスチャをサンプリングするUVとしてこの処理を嚙ませることで、区切られているブロックはすべて同じUV値を持つことになるためサンプリングされる画像の色もブロックごとの解像度になります。

　こうしてモザイクを実装している仕組みになります。

③フラグメントシェーダーでUVをPosterize_float2に渡します。

  fixed4 frag(v2f i) : SV_Target
            {
                float2 mosaic;
                Posterize_float2(i.uv, _mosaicSize.xy, mosaic);
                fixed4 col = tex2D(_MainTex, mosaic);

                return col;
           }

Posterize_float2では第三引数としてoutで返り値を得ることができます。

ここではfloat2型のmosaicという変数を定義し、このmosaicをtex2DのサンプリングのUVとして使用しています。

以上で画像をモザイクにするシェーダーが完成しました。

〇コード一覧

Shader "Unlit/mosaic"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _mosaicSize("Size",vector) = (1,1,1,1)
    }
    SubShader
    {
        Tags
        {
            "RenderType"="Opaque"
        }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
           
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            float4 _mosaicSize;
            void Posterize_float2(float2 In, float2 Steps, out float2 Out)
            {
                Out = floor(In / (1 / Steps)) * (1 / Steps);
            }

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                float2 mosaic;
                Posterize_float2(i.uv, _mosaicSize.xy, mosaic);
                fixed4 col = tex2D(_MainTex, mosaic);

                return col;
            }
            ENDCG
        }
    }
}