ゼロから始めるUnityShader開発 第六章 Unity座標で定義される球を使った表現

本日はShader枠です。

今回はUnityでワールド空間上に任意の点を等間隔で指定し、描画するシェーダー表現を行います。

〇完成物

〇Unityの座標で定義される球

Unityの座標空間上に一定間隔で定義される球表現は以下の関数で行います。

            float SphereGroupHard(float3 pos, float spacing, float radius)
            {
                // 等間隔グリッド上の最近接の中心座標を求める
                float3 gridCenter = round(pos / spacing) * spacing;
                // 現在位置とグリッド上の最近接中心との距離を計算
                float d = length(pos - gridCenter);
                // HLSLのstep関数は、step(edge, x)で、x < edgeなら0、x >= edgeなら1を返すので、その反転で内部が1となるようにする
                return 1.0 - step(radius, d);
            }

ここでgridCenterは座標を定数spacingで割った値をround関数で処理しています。

round関数は入力された浮動小数点を『最も近い整数』に丸めた値を返します。

具体的にはround(1.2)の場合は1を、round(1,6)であれば2を返します。

つまりgridCenterは定数spacingの間隔で座標を分割しているということができます。

この関数の引数float3 posに頂点シェーダーブロックでmul(unity_ObjectToWorld, v.vertex).xyz;によって求めたUnityワールド座標を与えることで、Unityの座標軸上で球領域を描画することができます。

今回はフラグメントシェーダーブロックで大きさにUnityのY座標軸を使用していることでY座標に応じて球のスケールが変わるようにしています。

            fixed4 frag(v2f i) : SV_Target
            {
                fixed4 col = float4(1, 1, 1, 1);
                col.a = SphereGroupHard(i.wpos, 0.1,  i.wpos.y*_Power + _EffectPos);
                return col;
            }

本日は以上です。

〇コード

Shader "Soda3DART/HoloMoto/TransitionShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        _EffectPos("EffectPos",Float) = 0.0
        _Power ("Power", Range(0, 1)) = 0.5
    }
    SubShader
    {
        Tags
        {
            "RenderType"="Transparent"
        }
        LOD 100
        //Cull front
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            float _Power;
            float _EffectPos;
            struct v2f
            {
                float2 uv : TEXCOORD0;
                float3 wpos : TEXCOORD1;
                float4 vertex : SV_POSITION;
            };

            float SphereGroupHard(float3 pos, float spacing, float radius)
            {
                // 等間隔グリッド上の最近接の中心座標を求める
                float3 gridCenter = round(pos / spacing) * spacing;
                // 現在位置とグリッド上の最近接中心との距離を計算
                float d = length(pos - gridCenter);
                // HLSLのstep関数は、step(edge, x)で、x < edgeなら0、x >= edgeなら1を返すので、その反転で内部が1となるようにする
                return 1.0 - step(radius, d);
            }

            v2f vert(appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.wpos = mul(unity_ObjectToWorld, v.vertex).xyz;
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                fixed4 col = float4(1, 1, 1, 1);
                col.a = SphereGroupHard(i.wpos, 0.1,  i.wpos.y*_Power + _EffectPos);
                return col;
            }
            ENDCG
        }
    }
}